to_kill_a_monarch/supercollider/tkam_gui.scd

(
var genWindow, masterView, faderView, buildGenerator, buildMetronome, buildTransport, buildAuxControls, buildMasterFader, buildTrackFader,
updateSection, updateSubsection, clockStringFunc, metronomeStringFunc, metronomeColorFunc, updateTransport,
currentSection = 1, currentSubsection = 1;

buildGenerator = {arg view;
	var ranSeed;
	HLayout(
		ranSeed = TextField(view, Rect(10, 10, 10, 20)).string_("19800725"),
		Button(view).states_([["reset seed"]]).action_({ ranSeed.string = "19800725"}.inEnvir),
		Button(view).states_([["random seed"]]).action_({ ranSeed.string = 50000000.rand.asString}.inEnvir),
		Button(view).states_([["generate"]]).action_({
			{~genAll.value(ranSeed.string.asInteger); ~appStatus.string = "status: ready"}.fork(AppClock);
			~appStatus.string = "status: generating"}.inEnvir),
		Button(view).states_([["transcribe"]]).action_({
			{~transcribe.value(~scoreData, ~sectionData); ~appStatus.string = "status: ready"}.fork(AppClock);
			~appStatus.string = "status: transcribing"}.inEnvir),
		[~appStatus = StaticText(view).string_("status: ready"), stretch: 1], nil)
};

// these funcs update the elements of the transport panel
clockStringFunc = {
	arg measure, beat;
	var measureString, beatString, leadSpace;
	measureString = measure.asInteger.asString;
	beatString = beat.asInteger.asString;
	leadSpace = (3 - measureString.size).collect({" "}).join;
	leadSpace ++ measureString ++ "." ++ beatString
};

// [-30, -105, -104] and [-30, -105, -113] are unicode inverse bullet and normal bullet, respectively
metronomeStringFunc = { arg beat; if(beat == 1,
	{[-30, -105, -104].collect({arg int; int.asAscii}).as(String)},
	{[-30, -105, -113].collect({arg int; int.asAscii}).as(String)})};
metronomeColorFunc = { arg beat; if(beat == 1, {Color.red},{Color.black})};

updateTransport = {arg clock, metronome, sectionDisplay, measure, beat, section, subsection;
	sectionDisplay.string = "section: " ++ section.asInteger ++ "." ++ subsection.asInteger;
	clock.string = clockStringFunc.value(measure, beat);
	metronome.stringColor = metronomeColorFunc.value(beat);
	metronome.string = metronomeStringFunc.value(beat);
	{0.75.wait; {metronome.string = ""}.defer}.fork(~tempoClock, quant: 0);
}.inEnvir;


buildMetronome = {arg win;
	var clock, metronome, layout;

	clock = StaticText(win).string_("  1.1").font_(Font("Liberation Mono", 200));
	metronome = StaticText(win).string_([-30, -105, -104].collect({arg int; int.asAscii})
			.as(String)).font_(Font("Liberation Mono", 300)).stringColor_(Color.red);

	layout = HLayout(
		clock,
		StaticText(win).string_("|").font_(Font("Liberation Mono", 200)),
		metronome
	);

	[clock, metronome, layout]
};

updateSection = {arg mod, clock, metronome, sectionDisplay, refresh = true;
	if(~sectionNavDict[[currentSection + mod, 1]] != nil, {
		currentSection = currentSection + mod;
		currentSubsection = 1;
		if(refresh, {
			updateTransport.value(clock, metronome, sectionDisplay,
				~sectionNavDict[[currentSection, currentSubsection]], 1,
				currentSection, currentSubsection
			);
		});
	});
};


updateSubsection = {arg mod, clock, metronome, sectionDisplay, refresh = true;
	if(~sectionNavDict[[currentSection, currentSubsection + mod]] != nil, {
		currentSubsection = currentSubsection + mod;
		if(refresh, {
			updateTransport.value(clock, metronome, sectionDisplay,
				~sectionNavDict[[currentSection, currentSubsection]], 1,
				currentSection, currentSubsection
			);
		});
	}, {updateSection.value(mod, clock, metronome, sectionDisplay, refresh)})
};

buildTransport = {arg win, view, clock, metronome;
	var sec, subsec, sectionDisplay, layout, player;

	sectionDisplay = StaticText(win).string_("section: 1.1").font_(Font("Liberation Mono", 70));

	OSCFunc({ arg msg, time;
		{
			var measure, beat, section, subsection;
			# measure, beat, section, subsection = msg[3..];
			currentSection = sec = section.asInteger;
			currentSubsection = subsec = subsection.asInteger;
			//currentSubsection.postln;
			updateTransport.value(clock, metronome, sectionDisplay, measure, beat, section, subsection);
		}.inEnvir.defer;
	},'/measureClock_' ++ ~hash, s.addr);

	//OSCdef(\externalAdvance ++ ~hash, {arg msg, time; {updateSection.value(1, clock, metronome, sectionDisplay, false)}.inEnvir.defer},'/nextSubsection_' ++ ~hash, s.addr);


	layout = HLayout(
		Button(view).states_([["<<", Color.black]]).action_({arg pState; updateSection.value(-1, clock, metronome, sectionDisplay)}.inEnvir),
		Button(view).states_([["<", Color.black]]).action_({arg pState; updateSubsection.value(-1, clock, metronome, sectionDisplay)}.inEnvir),
		Button(view).states_([["play", Color.black], ["stop", Color.black, Color.grey]]).action_({arg pState;
			if(pState.value == 1, {
				player = {
					var startMeasure = ~sectionNavDict[[currentSection, currentSubsection]] - 1;
					~patternProxy.source = Ppar(
						[Pseq(~patterns[0][startMeasure..], 1)] ++

						~patterns[2].collect({arg pattern, p;
							Pmono(\amp_curve_ ++ ~hash,
								\amp, Pseg(Pseq(pattern.slice(nil, 0)[(startMeasure * 16)..], 1), 1 * ~dUnit, \cub),
								\dur, 1 * ~dUnit,
								\bus, ~preampBusses[p].index
							)
						}) ++

						~patterns[1].collect({arg pattern, p;
							Pmono(\bass_mono_ ++ ~hash,
								\freq, Pseq(pattern.slice(nil, 0)[(startMeasure * 16)..], 1),
								\dur, 1 * ~dUnit,
								\ampBus, ~preampBusses[p + 1].index,
								\bus, ~postampBusses[4].index
							)
						})

					);
					Pbind(\instrument, \click_ ++ ~hash, \beat, Pseq([1, 2, 1, 2]), \dur, 1).play(~tempoClock, quant: 0);
					[1, 2, 1, 2].do({arg beat;
						{
							metronome.stringColor = metronomeColorFunc.value(beat);
							metronome.string = metronomeStringFunc.value(beat);
						}.defer;
						0.75.wait;
						{metronome.string = ""}.defer;
						0.25.wait;
					});
					~patternProxy.play(~tempoClock, quant: 0)
				}.fork(~tempoClock, quant: 0)
			}, {
				//subsec.postln;
				~patternProxy.pause;
				//player.stop;
				updateTransport.value(clock, metronome, sectionDisplay,
					~sectionNavDict[[currentSection, currentSubsection]], 1,
					currentSection.postln, currentSubsection.postln);
			});
		}.inEnvir),
		Button(view).states_([[">", Color.black]]).action_({arg pState; updateSubsection.value(1, clock, metronome, sectionDisplay)}.inEnvir),
		Button(view).states_([[">>", Color.black]]).action_({arg pState; updateSection.value(1, clock, metronome, sectionDisplay)}.inEnvir), nil,
		sectionDisplay, nil);
	[sectionDisplay, layout]
};


buildAuxControls = {arg view;
	var tempo, address, updateSection;
	HLayout(
		tempo = TextField(view).string_("60"),
		Button(view).states_([["set tempo"]]).action_({~tempoClock.tempo = tempo.string.asInteger / 60}.inEnvir),
		[StaticText(view).string_("  "), stretch: 1])
};


buildMasterFader = {arg view, masterVol, masterMute, masterIndicators;
	HLayout(
		VLayout(
			[HLayout(
				Slider(view).value_(0.8).action_(
					{arg v; masterVol = v.value * 1.25; ~play.set(\masterVol, masterVol)}.inEnvir),
				masterIndicators[0],
				masterIndicators[1]), stretch: 2],
			Button(view).states_([["mute", Color.black], ["mute", Color.black, Color.grey]]).action_(
				{arg v; masterMute = (1 - v.value).abs; ~play.set(\masterMute, masterMute)}.inEnvir),
			StaticText(view).string_("             master             ").align_(\center)
	), nil)
};


buildTrackFader = {arg view, name, index, initVal;
	var trackIndicator;

	trackIndicator = LevelIndicator();

	OSCFunc.new({arg msg; {trackIndicator.value = msg[3].ampdb.linlin(-50, 0, 0, 1)}.defer},
		'/trackLevel_' ++ index ++ "_" ++ ~hash, s.addr);

	HLayout(
		VLayout(
			HLayout(
				Slider(view).value_(0.8).action_(
					{arg v; var vol = v.value * 1.25; ~play.set(\vol_ ++ index, vol)}.inEnvir),
				trackIndicator),
			Button(view).states_([["mute", Color.black], ["mute", Color.black, Color.grey]]).action_(
				{arg v; var mute = (1 - v.value).abs; ~play.set(\mute_ ++ index, mute)}.inEnvir).value_(initVal),
			VLayout(
				StaticText(view).string_("pan").align_(\center),
				Knob(view).action_({arg v; var pan = v.value * 2 - 1; ~play.set(\pan_ ++ index, pan)}.inEnvir).value_(0.5)
			), //[StaticText(view).string_("  "), stretch: 0.1]
			StaticText(view).string_(name).align_(\center)
		),
		nil)
};


masterView = {arg win;
	var view, generatorLayout, clock, metronome, metronomeLayout, transportLayout, auxControlsLayout, countOff, ranSeed, order, tempo, sectionDisplay, address;

	view = View(win);
	generatorLayout = buildGenerator.value(view);
	# clock, metronome, metronomeLayout = buildMetronome.value(win);
	# sectionDisplay, transportLayout = buildTransport.value(win, view, clock, metronome);
	auxControlsLayout = buildAuxControls.value(view);

	view.layout_(
		HLayout(
			[
				VLayout(
					metronomeLayout,
					[StaticText(view).string_("  "), stretch: 1], //nil
					transportLayout,
					[StaticText(view).string_("  "), stretch: 1],
					auxControlsLayout,
					[StaticText(view).string_("  "), stretch: 1],
					generatorLayout),
				alignment: \top
			]
		)
	)
};


faderView = {arg win;
	var view, masterIndicators, trackIndicators, master, tracks;
	var partAbbr = ["*", "III", "II", "I", "accomp_I", "accomp_II", "click"];
	var trackNames = ["*", "III", "II", "I", "accomp_I", "accomp_II", "click"];
	var partVols, partMutes, partPans;
	var masterMute, masterVol;

	// set initial mixer values
	partVols = [1, 1, 1, 1, 1, 1];
	partMutes = [0, 1, 1, 1, 1, 0];
	partPans = [0, 0, 0, 0, 0, 0];
	masterMute = 1;
	masterVol = 1;

	view = View(win);
	masterIndicators = {LevelIndicator()} ! 2;
	trackIndicators = {LevelIndicator()} ! 6;

	master = buildMasterFader.value(view, masterVol, masterMute, masterIndicators);
	tracks = {arg part;
		buildTrackFader.value(view, trackNames[part], part, 0);
	} ! 7;
	view.layout_(HLayout(master, nil, *tracks))
};


~generateGUI = {
	var win, tabButtonReset, transportButton, mixerButton, helpButton, tabs;
	win = Window("to kill a monarch", Rect(500, 500, 1100, 575), false).front;
	tabButtonReset = {transportButton.value = 1; mixerButton.value = 1; helpButton.value = 1};
	win.layout = VLayout(
		HLayout(
			HLayout(
				[
					transportButton = Button().states_([["transport", Color.white, Color.grey], ["transport", Color.black]]).action_(
						{tabButtonReset.value; transportButton.value = 0; tabs.index = 0 }.inEnvir).value_(0), stretch: 1
				], [
					mixerButton = Button().states_([["mixer", Color.white, Color.grey], ["mixer", Color.black]]).action_(
						{tabButtonReset.value; mixerButton.value = 0; tabs.index = 1 }.inEnvir).value_(1), stretch: 1
				]
			),
			helpButton = Button().states_([["help", Color.white, Color.grey], ["help", Color.black]]).action_(
				{tabButtonReset.value; helpButton.value = 0; tabs.index = 2 }.inEnvir).value_(1)
		),
		tabs = StackLayout(masterView.value(win), faderView.value(win)/*, helpView.value*/));
};
//~generateGUI.value
)